;右クリックで終了
#define BUTTON_MAX 3	;画像の数
#define BUTTON_W 90	;画像の幅
#define BUTTON_H 40	;画像の高さ
*main
;----------------変数の初期化-------------------
	dim button_x,BUTTON_MAX
	dim button_y,BUTTON_MAX
	button_x=100,200,300	;画像の左上のX座標
	button_y=50,100,150	;画像の左上のY座標

;----------------画面の準備-------------------
	buffer 2
	picload "button.bmp"	;バッファーに画像を読み込む
	gsel 0
*view
	repeat BUTTON_MAX
		pos button_x.cnt,button_y.cnt
		gcopy 2,BUTTON_W*cnt,0,BUTTON_W,BUTTON_H	;画像を表示
	loop

;----------------どこにマウスがあるか判定-------------------
*kurikaesi
	await 1
	number=-1		;何番目の画像か
	repeat BUTTON_MAX
		if mousex < button_x.cnt : continue
		if mousex > (button_x.cnt+BUTTON_W) : continue
		if mousey < button_y.cnt : continue
		if mousey > (button_y.cnt+BUTTON_H) : continue
		number=cnt	;押されたボタンをnumberに
		break
	loop
	if number==-1 : goto *view		;画像の上ではない


	pos button_x.number,button_y.number
	gcopy 2,BUTTON_W*number,BUTTON_H,BUTTON_W,BUTTON_H	;画像を書き換える

;----------------入力確認-------------------
	click_stat=0
	stick click_stat
	if click_stat==512 : end		;右クリックされた
	if click_stat!256 : goto *kurikaesi	;左クリックされていない

	if number==0 : dialog "赤ボタンが選ばれました"
	if number==1 : dialog "青ボタンが選ばれました"
	if number==2 : dialog "緑ボタンが選ばれました"

	goto *kurikaesi