#define x0 50					;テキストの初期表示位置
#define y0 50					;テキストの初期表示位置
;--------------------変数の初期化------------------
	exist "start.txt"			;ファイルサイズ取得
	sdim t_data,strsize : notesel t_data	;メモリノートパッド命令のバッファに指定
	bload "start.txt",t_data		;テキスト読み出し
	notemax line_max			;テキストの行数を取得

	sdim t_one,100				;一行分のテキストを入れる
	sdim char,3				;日本語一文字などを入れる
	line_now=0				;現在のテキストの行数

	counter=0				;文字数など
	f_size=25				;フォントサイズ
	f_name="ＭＳ 明朝"			;フォント名
	font f_name,f_size,1			;フォント指定
	t_wait=1				;テキストウェイト
	x=x0 : y=y0				;テキスト表示位置

;--------------------メインループ------------------
	repeat
		noteget t_one,line_now		;テキストから一行読みだし
		gosub *text_view		;その一行を表示
		line_now++			;次の行へ
		if line_now==line_max : break	;テキストの最後で終わり
	loop
	stop

;--------------------サブルーチン------------------
;--------------------テキスト表示------------------
*text_view
	strlen counter,t_one			;文字数を数える（日本語だけとする）
	repeat counter/2			;この半分が文字数である（２byteなので）
		strmid char,t_one,cnt*2,2	;一文字抜き出し
		color 0,0,0 : pos x+1,y+1 : mes char	;影表示
		color 0,128,255 : pos x,y : mes char	;文字表示
		x+=f_size				;表示位置をずらす
		wait t_wait				;ウェイト
	loop
	x=x0 : y+=f_size			;表示位置修正
	return